Help with plotscripting

[AzureGames]

How do I make my song "Fade out", or in other words, make it get quieter and quieter until you can no longer hear it??

[Gizmog]

SetMusicVolume command and a for loop. It'll look something, but not exactly, like this:

Code: Select all

GlobalVariable (1,MusicVolume)

plotscript,FadeMusicOut,begin
variable (Loop)
MusicVolume := GetMusicVolume
for (Loop,MusicVolume,0,-1)
do (
     SetMusicVolume (Loop)
     wait (1)
    )
end

plotscript,FadeMusicIn,begin
variable (Loop)
for (Loop,0,MusicVolume,1)
do (
     SetMusicVolume (Loop)
     wait (1)
     )
end

[Taco Bot]

Also be aware that the music volume will be different depending on game settings and what backend of the OHR you're using. You'd probably be best saving the volume to a variable before fading out so you can return it to its previous level.

[TMC]

Music volume shouldn't* depend on the backend ... with the possible exception of MIDI volume, which is quirky (and I can't remember the quirks anymore). But yes, because the player can adjust the volume you should fade to/from whatever the initial volume level is. Which is exactly what the scripts posted by Giz do.

However, music volume has a range of 0 to 255, defaulting to 128, so that script is going to take 128 ticks to fade, which is 7 seconds. You might want to speed that up (this does it in 3 seconds):

Code: Select all

DefineConstant (54, MusicFadeTicks)  # 18 * 3 seconds = 54 ticks
GlobalVariable (1,MusicVolume)

plotscript,FadeMusicOut, begin
variable (Loop)
MusicVolume := GetMusicVolume
for (Loop,MusicFadeTicks,0,-1)
do (
     SetMusicVolume (MusicVolume * Loop / MusicFadeTicks)
     wait (1)
    )
end

plotscript,FadeMusicIn, begin
variable (Loop)
for (Loop,0,MusicFadeTicks,1)
do (
     SetMusicVolume (MusicVolume * Loop / MusicFadeTicks)
     wait (1)
     )
end 

(Why did I use a constant? Because script default arguments are ignored when triggering a script from a textbox)

* (Boring technical stuff) By "shouldn't" I mean, we don't intend for it to, and you can assume that it doesn't, since everyone uses music_sdl. To my surprise music_native/native2 don't even support changing the volume, which is one reason why we stopped suggesting anyone use it.

[Taco Bot]

Oh shoot, looks like I didn't read through the script as thoroughly as I thought...

Sorry, I need to get more sleep before attempting to make forum posts.

[Gizmog]

TMC's script is pretty good, but look at how much code he duplicates! So sloppy! You can also do it this way, which looks fancier and uses fewer lines of code.

Code: Select all

DefineConstant (54, MusicFadeTicks)  # 18 * 3 seconds = 54 ticks
GlobalVariable (1,MusicVolume)  

plotscript,FadeMusicOut,begin
MusicVolume := GetMusicVolume
FadeMusic (MusicFadeTicks,0,-1)
end

plotscript,FadeMusicIn,begin
FadeMusic (0,MusicFadeTicks,1)
end

script,FadeMusic,Start,Finish,InOrOut=1,begin
for (Loop,Start,Finish,InOrOut) 
do ( 
     SetMusicVolume (MusicVolume * Loop / MusicFadeTicks) 
     wait (1) 
     ) 
end

[TMC]

Don't make me pull my trump card, and build it into the engine!

[AzureGames]

SetMusicVolume command and a for loop. It'll look something, but not exactly, like this:

Code: Select all

GlobalVariable (1,MusicVolume)

plotscript,FadeMusicOut,begin
variable (Loop)
MusicVolume := GetMusicVolume
for (Loop,MusicVolume,0,-1)
do (
     SetMusicVolume (Loop)
     wait (1)
    )
end

plotscript,FadeMusicIn,begin
variable (Loop)
for (Loop,0,MusicVolume,1)
do (
     SetMusicVolume (Loop)
     wait (1)
     )
end